**Лабораторная работа 8**

**Сценарии WSH для доступа к службе каталогов АDSI**

**Список всех доступных доменов в локальной сети**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ListDomains.vbs

' Язык: VBScript

' Описание: Вывод на экран списка всех доменов локальной сети

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

'Объявляем переменные

Dim objNameSpace ' Корневой объект Namespace

Dim objDomain ' Экземпляр объекта Domain

Dim strResult ' Строка для вывода на экран

'Связываемся с корневым объектом Namespace

Set objNameSpace = GetObject("WinNT:")

'Устанавливаем фильтр для выделения объектов-доменов

objNameSpace.Filter = Array("domain")

strResult = "Все доступные домены в сети:" & vbCrLf & vbCrLf

' Перебираем элементы коллекции

For Each objDomain In objNameSpace

'Формируем строку с именами доменов

strResult = strResult & objDomain.Name & vbCrLf


Next

'Вывод информацию на экран

WScript.Echo strResult

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 8.1. Вывод на экран списка всех доменов локальной сети



**Создание пользователя и группы на рабочей станции**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: AddUser.vbs

' Язык: VBScript

' Описание: Создание нового пользователя компьютера

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

'Объявляем переменные

Dim objComputer ' Экземпляр объекта Computer

Dim objUser ' Экземпляр объекта User

Dim strUser ' Имя создаваемого пользователя

' Задаем имя пользователя

strUser = "XUser"

' Связываемся с компьютером Popov

Set objComputer = GetObject("WinNT://Popov")

' Создаем объект класса User

Set objUser = objComputer.Create("user",strUser)

' Добавляем описание созданного пользователя


objUser.Description = "Этот пользователь создан из сценария ADSI"

' Сохраняем информацию на компьютере

objUser.SetInfo

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 8.2. Создание нового локального пользователя на рабочей станции



Группа на рабочей станции создается аналогичным образом (листинг 8.3).

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: AddGroup.vbs

' Язык: VBScript

' Описание: Создание новой группы на компьютере

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

'Объявляем переменные

Dim objComputer ' Экземпляр объекта Computer

Dim objGroup ' Экземпляр объекта Group

Dim strGroup ' Имя создаваемой группы

' Задаем имя пользователя

strGroup = "XGroup"

' Связываемся с компьютером Popov

Set objComputer = GetObject("WinNT://Popov")

' Создаем объект класса Group


Set objGroup = objComputer.Create("group",strGroup)

' Сохраняем информацию на компьютере

objGroup.SetInfo

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 8.3. Создание новой локальной группы на рабочей станции



**Вывод информации о пользователе и смена его пароля**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: UserInfo.vbs

' Язык: VBScript

' Описание: Вывод информации о пользователе компьютера и смена

' его пароля

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

'Объявляем переменные

Dim objUser ' Экземпляр объекта User

Dim WshShell ' Объект WshShell

Dim Res ' Результат нажатия кнопки в диалоговом окне

Dim strPassword ' Строка с новым паролем

Dim strResult ' Строка для вывода на экран

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* Начало \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Связываемся с пользователем XUser компьютера Popov

Set objUser = GetObject("WinNT://Popov/XUser,user")

' Формируем строку с информацией о пользователе

strResult = "Информация о пользователе XUser" & vbCrLf &\_

"Имя: " & objUser.Name & vbCrLf & \_

"Описание: " & objUser.Description & vbCrLf

' Выводим сформированную строку на экран

WScript.Echo strResult

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

' Запрос на изменение пароля

Res = WshShell.Popup("Изменить пароль у XUser?",0,\_

"Администрирование пользователей",vbQuestion+vbYesNo)

If Res=vbYes Then ' Нажата кнопка Да

' Устанавливаем новый пароль

objUser.SetPassword "NewPassword"

' Сохраняем сделанные изменения

objUser.SetInfo

WScript.Echo "Пароль был изменен"


Else

WScript.Echo "Вы отказались от изменения пароля"

End If

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 8.4. Вывод информации о пользователе компьютера и смена его пароля



**Удаление пользователя и группы на рабочей станции**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: DelUserAndGroup.vbs

' Язык: VBScript

' Описание: Удаление пользователя и группы компьютера

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

On Error Resume Next

'Объявляем переменные

Dim objComputer ' Экземпляр объекта Computer

Dim strUser ' Имя удаляемого пользователя

Dim strGroup ' Имя удаляемой группы

Dim WshShell ' Объект WshShell

Dim strMess Строка для вывода на экран

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* Начало \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя удаляемого пользователя

strUser = "XUser"

' Имя удаляемой группы

strGroup = "XGroup"

' Связываемся с компьютером Popov

Set objComputer = GetObject("WinNT://Popov")

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

'\*\*\*\*\*\*\*\*\*\*\*\*\* Удаление пользователя \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Удаляем пользователя

objComputer.Delete "user", strUser

' Обрабатываем ошибки

If Err.Number <> 0 Then

strMess="Ошибка при удалении пользователя " & strUser & vbCrLf & \_

"Код ошибки: " & Err.number & "Описание: " & Err.description

WshShell.Popup strMess,0,"Удаление пользователя",vbCritical

' Очищаем свойства объекта Err

Err.Clear

Else

' Все в порядке

strMess = "Пользователь " & strUser & " удален"

WshShell.Popup strMess,0,"Удаление пользователя",vbInformation

End If

'\*\*\*\*\*\*\*\*\*\*\*\*\* Удаление группы \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

objComputer.Delete "group", strGroup

' Обрабатываем ошибки

If Err.Number <> 0 Then

strMess="Ошибка при удалении группы " & strGroup & vbCrLf & \_

"Код ошибки: " & Err.number & "Описание: " & Err.description

' Очищаем свойства объекта Err

Err.Clear

Else

' Все в порядке


strMess="Группа " & strGroup & " удалена"

WshShell.Popup strMess,0,"Удаление группы",vbInformation

End If

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 8.5. Удаление пользователя и группы на рабочей станции



**Список всех групп на рабочей станции**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ListAllGroups.vbs

' Язык: JScript

' Описание: Вывод на экран имен всех групп заданного компьютера

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

'Объявляем переменные

Dim objComputer ' Экземпляр объекта Computer

Dim objGroup ' Экземпляр объекта Group

Dim strResult ' Строка для вывода на экран

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* Начало \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Связываемся с компьютером Popov

Set objComputer = GetObject("WinNT://Popov")

strResult = "На компьютере Popov созданы группы:" & vbCrLf & vbCrLf

' Перебираем элементы коллекции

For Each objGroup In objComputer

' Выделяем объекты класса Group

If objGroup.Class = "Group" Then

'Формируем строку с именами групп

strResult = strResult & objGroup.Name & vbCrLf

End If


Next

'Выводим информацию на экран

WScript.Echo strResult

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 8.6. Вывод на экран имен всех локальных групп заданной рабочей станции



**Список всех пользователей в группе**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ListUsers.vbs

' Язык: VBScript

' Описание: Вывод на экран имен всех пользователей заданной группы

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

'Объявляем переменные

Dim objGroup ' Экземпляр объекта Group

Dim objUser ' Экземпляр объекта User

Dim strResult ' Строка для вывода на экран

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* Начало \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Связываемся с группой Пользователи компьютера Popov

Set objGroup = GetObject("WinNT://Popov/Пользователи,group")

strResult = "Все пользователи группы Пользователи на компьютере Popov:" & vbCrLf

' Перебираем элементы коллекции

For Each objUser In objGroup.Members()

' Формируем строку с именами пользователей

strResult = strResult & objUser.Name & vbCrLf

Next

' Вывод информации на экран

WScript.Echo strResult

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 8.7. Вывод на экран имен всех пользователей заданной группы

